blob: 9be9dcefa8cb75757762c5bead9838fe68e8652a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
###############################################################################
# Top contributors (to current version):
# Aina Niemetz, Mathias Preiner, Gereon Kremer
#
# This file is part of the cvc5 project.
#
# Copyright (c) 2009-2021 by the authors listed in the file AUTHORS
# in the top-level source directory and their institutional affiliations.
# All rights reserved. See the file COPYING in the top-level source
# directory for licensing information.
# #############################################################################
#
# The build system configuration.
##
find_package(GTest REQUIRED)
include_directories(.)
include_directories(${PROJECT_SOURCE_DIR}/src)
include_directories(${PROJECT_SOURCE_DIR}/src/include)
include_directories(${CMAKE_BINARY_DIR}/src)
#-----------------------------------------------------------------------------#
# Add target 'units', builds and runs
# > unit tests
add_custom_target(build-units)
add_dependencies(build-tests build-units)
add_custom_target(units
COMMAND ctest --output-on-failure -L "unit" -j${CTEST_NTHREADS} $$ARGS
DEPENDS build-units)
set(CVC5_UNIT_TEST_FLAGS_BLACK
-D__BUILDING_CVC5LIB_UNIT_TEST -D__BUILDING_CVC5PARSERLIB_UNIT_TEST)
# Generate and add unit test.
macro(cvc5_add_unit_test is_white name output_dir)
set(test_src ${CMAKE_CURRENT_LIST_DIR}/${name}.cpp)
add_executable(${name} ${test_src})
target_compile_definitions(${name} PRIVATE ${CVC5_UNIT_TEST_FLAGS_BLACK})
target_link_libraries(${name} PUBLIC main-test GMP)
target_link_libraries(${name} PUBLIC GTest::Main)
target_link_libraries(${name} PUBLIC GTest::GTest)
if(USE_POLY)
# Make libpoly headers available for tests
target_include_directories(${name} PRIVATE "${Poly_INCLUDE_DIR}")
endif()
if(${is_white})
target_compile_options(${name} PRIVATE -fno-access-control)
endif()
# Disable the Wunused-comparison warnings for the unit tests.
# We check for `-Wunused-comparison` and then add `-Wno-unused-comparison`
check_cxx_compiler_flag("-Wunused-comparison" HAVE_CXX_FLAGWunused_comparison)
if(HAVE_CXX_FLAGWunused_comparison)
target_compile_options(${name} PRIVATE -Wno-unused-comparison)
endif()
add_dependencies(build-units ${name})
# Generate into bin/test/unit/<output_dir>.
set(test_bin_dir ${CMAKE_BINARY_DIR}/bin/test/unit/${output_dir})
set_target_properties(${name}
PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${test_bin_dir})
# The test target is prefixed with test identifier 'unit/' and the path,
# e.g., for '<output_dir>/myunittest.h'
# we create test target 'unit/<output_dir>/myunittest'
# and run it with 'ctest -R "example/<output_dir>/myunittest"'.
if("${output_dir}" STREQUAL "")
set(test_name unit/${name})
else()
if("${output_dir}" STREQUAL "api")
set(test_name unit/${output_dir}/cpp/${name})
else()
set(test_name unit/${output_dir}/${name})
endif()
endif()
add_test(${test_name} ${test_bin_dir}/${name})
set_tests_properties(${test_name} PROPERTIES LABELS "unit")
endmacro()
macro(cvc5_add_unit_test_black name output_dir)
cvc5_add_unit_test(FALSE ${name} ${output_dir})
endmacro()
macro(cvc5_add_unit_test_white name output_dir)
cvc5_add_unit_test(TRUE ${name} ${output_dir})
endmacro()
add_subdirectory(api)
add_subdirectory(base)
add_subdirectory(context)
add_subdirectory(node)
add_subdirectory(main)
add_subdirectory(parser)
add_subdirectory(printer)
add_subdirectory(prop)
add_subdirectory(theory)
add_subdirectory(preprocessing)
add_subdirectory(util)
|
