blob: c68cdc95d1d66843e3b29cf09a15d9e9c40e52e6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
#####################
## CMakeLists.txt
## Top contributors (to current version):
## Makai Mann, Mathias Preiner
## This file is part of the CVC4 project.
## Copyright (c) 2009-2021 by the authors listed in the file AUTHORS
## in the top-level source directory and their institutional affiliations.
## All rights reserved. See the file COPYING in the top-level source
## directory for licensing information.
##
if(POLICY CMP0057)
# For cmake >= 3.3 this policy changed the behavior of IN_LIST
# if the policy exists, we use the NEW behavior
cmake_policy(SET CMP0057 NEW)
endif()
find_package(PythonExtensions REQUIRED)
find_package(Cython 0.29 REQUIRED)
# Generate cvc4kinds.{pxd,pyx}
configure_file(genkinds.py.in genkinds.py)
set(GENERATED_FILES
"${CMAKE_CURRENT_BINARY_DIR}/cvc4kinds.pxd"
"${CMAKE_CURRENT_BINARY_DIR}/cvc4kinds.pxi"
)
add_custom_command(
OUTPUT
${GENERATED_FILES}
BYPRODUCTS
${GENERATED_FILES}
COMMAND
"${PYTHON_EXECUTABLE}"
"${CMAKE_CURRENT_BINARY_DIR}/genkinds.py"
--kinds-header "${PROJECT_SOURCE_DIR}/src/api/cpp/cvc5_kind.h"
--kinds-file-prefix "${CMAKE_CURRENT_BINARY_DIR}/cvc4kinds"
DEPENDS
"${CMAKE_CURRENT_BINARY_DIR}/genkinds.py"
"${PROJECT_SOURCE_DIR}/src/api/cpp/cvc5_kind.h"
)
add_custom_target(cvc4kinds DEPENDS ${GENERATED_FILES})
include_directories(${CMAKE_CURRENT_BINARY_DIR}) # for cvc4kinds.pxi
add_cython_target(pycvc4 CXX)
add_library(pycvc4
MODULE
${pycvc4})
add_dependencies(pycvc4 cvc4kinds)
target_include_directories(pycvc4
PRIVATE
${PYTHON_INCLUDE_DIRS}
${PROJECT_SOURCE_DIR}/src # for API headers in src/api/cpp
${CMAKE_BINARY_DIR}/src # for cvc4_export.h
)
target_link_libraries(pycvc4 cvc4 ${PYTHON_LIBRARIES})
# Disable -Werror and other warnings for code generated by Cython.
# Note: Visibility is reset to default here since otherwise the PyInit_...
# function will not be exported correctly
# (https://github.com/cython/cython/issues/3380).
set_target_properties(pycvc4
PROPERTIES
COMPILE_FLAGS
"-Wno-error -Wno-shadow -Wno-implicit-fallthrough"
CXX_VISIBILITY_PRESET default
VISIBILITY_INLINES_HIDDEN 0)
python_extension_module(pycvc4)
# Installation based on https://bloerg.net/2012/11/10/cmake-and-distutils.html
# Create a wrapper python directory and generate a distutils setup.py file
configure_file(setup.py.in setup.py)
set(PYCVC5_MODULE "${CMAKE_CURRENT_BINARY_DIR}/pycvc4")
file(MAKE_DIRECTORY "${PYCVC5_MODULE}")
file(WRITE ${PYCVC5_MODULE}/__init__.py
"import sys
from .pycvc4 import *
# fake a submodule for dotted imports, e.g. from pycvc4.kinds import *
sys.modules['%s.%s'%(__name__, kinds.__name__)] = kinds")
set(PYCVC5_LOC "${PYCVC5_MODULE}/$<TARGET_FILE_NAME:pycvc4>")
add_custom_command(TARGET pycvc4 POST_BUILD
COMMAND ${CMAKE_COMMAND} -E rename $<TARGET_FILE:pycvc4> ${PYCVC5_LOC}
)
# figure out if we're in a virtualenv
execute_process(OUTPUT_VARIABLE IN_VIRTUALENV
COMMAND
"${PYTHON_EXECUTABLE}"
-c
"from __future__ import print_function; import os;
print('YES' if 'VIRTUAL_ENV' in os.environ else 'NO', end='')")
set(INSTALL_CMD
"${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/setup.py install")
# if we're in a virtualenv, we install it in the virtualenv lib location
if ("${IN_VIRTUALENV}" STREQUAL "NO")
set(INSTALL_CMD "${INSTALL_CMD} --prefix=${CMAKE_INSTALL_PREFIX}")
endif()
message("Python bindings install command: ${INSTALL_CMD}")
install(CODE "execute_process(COMMAND ${INSTALL_CMD})"
FILE_PERMISSIONS OWNER_EXECUTE OWNER_WRITE OWNER_READ)
|