1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
|
# CVC4_SUPPORTED_BINDINGS
# -----------------------
# Supported language bindings for CVC4.
AC_DEFUN([CVC4_SUPPORTED_BINDINGS],
[c,java,csharp,perl,php,python,ruby,tcl,ocaml])
# CVC4_CHECK_BINDINGS(DEFAULT_BINDINGS_LIST)
# ------------------------------------------
# Check for user language binding preferences, and what is possible
# to build on the build host.
AC_DEFUN([CVC4_CHECK_BINDINGS], [
dnl Check for SWIG (for building language bindings)
noswig=no
m4_foreach(lang,[CVC4_SUPPORTED_BINDINGS],
[[cvc4_build_]]lang[[_bindings=no
]])
AC_ARG_VAR(SWIG, [SWIG binary (used to generate language bindings)])
AC_ARG_WITH([swig],
[AS_HELP_STRING([--with-swig=BINARY], [path to swig binary])],
[if test "$withval" = no; then noswig=yes; else SWIG="$withval"; fi])
AC_ARG_ENABLE([language-bindings],
[AS_HELP_STRING([--enable-language-bindings=][CVC4_SUPPORTED_BINDINGS][ | all], [specify language bindings to build])],
[if test "$enableval" = yes; then cvc4_check_for_bindings=yes; try_bindings='$1'; else cvc4_check_for_bindings=no; if test "$enableval" = no; then try_bindings=; else try_bindings="$enableval"; fi; fi],
[cvc4_check_for_bindings=no; try_bindings=])
CVC4_LANGUAGE_BINDINGS=
if test "$noswig" = yes; then
AC_MSG_WARN([use of swig disabled by user.])
SWIG=
if test "$cvc4_check_for_bindings" = no -a -n "$try_bindings"; then
AC_MSG_ERROR([language bindings requested by user, but swig disabled.])
fi
else
if test -z "$SWIG"; then
AC_CHECK_PROGS(SWIG, [swig swig2.0], swig, [])
else
AC_CHECK_PROG(SWIG, "$SWIG", "$SWIG", [])
fi
if test -z "$SWIG"; then
AC_MSG_WARN([language bindings disabled, swig not found.])
if test "$cvc4_check_for_bindings" = no -a -n "$try_bindings"; then
AC_MSG_ERROR([language bindings requested by user, but swig disabled.])
fi
else
AC_MSG_CHECKING([for requested user language bindings])
if test "$try_bindings" = all; then
try_bindings='CVC4_SUPPORTED_BINDINGS'
fi
try_bindings=$(echo "$try_bindings" | sed 's/,/ /g')
if test -z "$try_bindings"; then
AC_MSG_RESULT([none])
else
AC_MSG_RESULT([$try_bindings])
fi
cvc4_save_CPPFLAGS="$CPPFLAGS"
cvc4_save_CXXFLAGS="$CXXFLAGS"
AC_LANG_PUSH([C++])
for binding in $try_bindings; do
binding_error=no
AC_MSG_CHECKING([for availability of $binding binding])
case "$binding" in
c++)
AC_MSG_RESULT([C++ is built by default]);;
c)
cvc4_build_c_bindings=yes
AC_MSG_RESULT([C support will be built]);;
java)
AC_MSG_RESULT([Java support will be built])
AC_ARG_VAR(JAVA_CPPFLAGS, [flags to pass to compiler when building Java bindings])
CPPFLAGS="$CPPFLAGS $JAVA_CPPFLAGS"
AC_CHECK_HEADER([jni.h], [cvc4_build_java_bindings=yes], [binding_error=yes])
;;
csharp)
AC_MSG_RESULT([[C# support will be built]])
AC_ARG_VAR(CSHARP_CPPFLAGS, [flags to pass to compiler when building C# bindings])
CPPFLAGS="$CPPFLAGS $CSHARP_CPPFLAGS"
cvc4_build_csharp_bindings=yes
;;
perl)
AC_MSG_RESULT([perl support will be built])
AC_ARG_VAR(PERL_CPPFLAGS, [flags to pass to compiler when building perl bindings])
CPPFLAGS="$CPPFLAGS $PERL_CPPFLAGS"
AC_CHECK_HEADER([EXTERN.h], [cvc4_build_perl_bindings=yes], [binding_error=yes])
;;
php)
AC_MSG_RESULT([php support will be built])
AC_ARG_VAR(PHP_CPPFLAGS, [flags to pass to compiler when building PHP bindings])
CPPFLAGS="$CPPFLAGS $PHP_CPPFLAGS"
AC_CHECK_HEADER([zend.h], [cvc4_build_php_bindings=yes], [binding_error=yes])
;;
python)
AC_MSG_RESULT([python support will be built])
AM_PATH_PYTHON([2.5], [cvc4_build_python_bindings=yes], [binding_error=yes])
AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
AS_IF([test -z "$PYTHON_INCLUDE"], [
AS_IF([test -z "$PYTHON_CONFIG"], [
AC_PATH_PROGS([PYTHON_CONFIG],
[python$PYTHON_VERSION-config python-config],
[no]
)
AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON.])])
])
AC_MSG_CHECKING([python include flags])
AC_SUBST(PYTHON_CXXFLAGS, `$PYTHON_CONFIG --includes`)
AC_MSG_RESULT([$PYTHON_CXXFLAGS])
])
CPPFLAGS="$CPPFLAGS $PYTHON_CXXFLAGS"
AC_CHECK_HEADER([Python.h], [cvc4_build_python_bindings=yes], [binding_error=yes])
;;
ruby)
AC_MSG_RESULT([ruby support will be built])
AC_ARG_VAR(RUBY_CPPFLAGS, [flags to pass to compiler when building ruby bindings])
CPPFLAGS="$CPPFLAGS $RUBY_CPPFLAGS"
AC_CHECK_HEADER([ruby.h], [cvc4_build_ruby_bindings=yes], [binding_error=yes])
;;
tcl)
AC_MSG_RESULT([tcl support will be built])
AC_ARG_VAR(TCL_CPPFLAGS, [flags to pass to compiler when building tcl bindings])
CPPFLAGS="$CPPFLAGS $TCL_CPPFLAGS"
AC_CHECK_HEADER([tcl.h], [cvc4_build_tcl_bindings=yes], [binding_error=yes])
;;
ocaml)
AC_MSG_RESULT([OCaml support will be built])
AC_ARG_VAR(TCL_CPPFLAGS, [flags to pass to compiler when building OCaml bindings])
CPPFLAGS="$CPPFLAGS $OCAML_CPPFLAGS"
AC_CHECK_HEADER([caml/misc.h], [cvc4_build_ocaml_bindings=yes], [binding_error=yes])
if test "$binding_error" = no; then
AC_ARG_VAR(OCAMLC, [OCaml compiler])
if test -z "$OCAMLC"; then
AC_CHECK_PROGS(OCAMLC, ocamlc, ocamlc, [])
else
AC_CHECK_PROG(OCAMLC, "$OCAMLC", "$OCAMLC", [])
fi
AC_ARG_VAR(OCAMLMKTOP, [OCaml runtime-maker])
if test -z "$OCAMLMKTOP"; then
AC_CHECK_PROGS(OCAMLMKTOP, ocamlmktop, ocamlmktop, [])
else
AC_CHECK_PROG(OCAMLMKTOP, "$OCAMLMKTOP", "$OCAMLMKTOP", [])
fi
AC_ARG_VAR(OCAMLFIND, [OCaml-find binary])
if test -z "$OCAMLFIND"; then
AC_CHECK_PROGS(OCAMLFIND, ocamlfind, ocamlfind, [])
else
AC_CHECK_PROG(OCAMLFIND, "$OCAMLFIND", "$OCAMLFIND", [])
fi
AC_ARG_VAR(CAMLP4O, [camlp4o binary])
if test -z "$CAMLP4O"; then
AC_CHECK_PROGS(CAMLP4O, camlp4o, camlp4o, [])
else
AC_CHECK_PROG(CAMLP4O, "$CAMLP4O", "$CAMLP4O", [])
fi
fi
;;
*) AC_MSG_RESULT([unknown binding]); binding_error=yes;;
esac
if test "$binding_error" = yes; then
if test "$cvc4_check_for_bindings" = no; then
AC_MSG_ERROR([Language binding \`$binding' requested by user, but it cannot be built (the preceding few lines should give an indication why this is).])
else
AC_MSG_WARN([Language binding \`$binding' cannot be built (the preceding few lines should give an indication why this is).])
fi
else
CVC4_LANGUAGE_BINDINGS="${CVC4_LANGUAGE_BINDINGS:+$CVC4_LANGUAGE_BINDINGS }$binding"
fi
AC_LANG_POP([C++])
CXXFLAGS="$cvc4_save_CXXFLAGS"
CPPFLAGS="$cvc4_save_CPPFLAGS"
done
fi
fi
m4_foreach([lang], [CVC4_SUPPORTED_BINDINGS],
[AM_CONDITIONAL([CVC4_LANGUAGE_BINDING_]m4_toupper(lang), [test "$cvc4_build_]lang[_bindings" = yes])
])dnl
AC_SUBST(SWIG)
AC_SUBST(CVC4_LANGUAGE_BINDINGS)
])# CVC4_CHECK_BINDINGS
|
